Diagrama de temas

  • BIENVENIDA

                                                                       ¡Bienvenidos al Primer Semestre!



                                                                


       Lógica y Diagramación

    El lenguaje del pensamiento estructurado. Diseñando los cimientos lógicos para las tecnologías y la gestión del mañana.

       ¿Por qué Lógica y Diagramación?

    Independientemente de tu especialidad, esta materia te enseñará a descomponer problemas complejos en soluciones lógicas, secuenciales y visualmente claras.

       ¿Qué Aprenderás Aquí?

    Lógica Pura

    Entrenarás tu mente para pensar de forma estructurada. Aprenderás lógica proposicional, toma de decisiones lógica y resolución metódica de problemas.

    Diagramación

    Dominarás la representación visual de procesos mediante diagramas de flujo normalizados, árboles de decisión e ingeniería de algoritmos.

    Optimización

    Aprenderás a buscar la solución más eficiente, eliminando cuellos de botella y reduciendo pasos innecesarios en cualquier sistema.

    La Materia en tu Profesión

    Análisis de Sistemas

    Diseña la arquitectura lógica y lógica de programación de cualquier software antes de escribir una sola línea de código.

    Electrónica

    Domina compuertas lógicas, diagramación de señales y lógica secuencial aplicada al hardware y automatización industrial.

    Administración

    Mapea procesos operativos, flujos de trabajo de negocio y optimiza tomas de decisiones críticas mediante diagramación.

             El Arte de Diagramar

    El poder de lo visual

    Un diagrama de flujo bien diseñado es un lenguaje universal que conecta programadores, ingenieros y directores de negocio sin barreras lingüísticas.

    • Terminales e Inicio: Define dónde arranca y termina el flujo.
    • Cajas de Decisión: Bifurcaciones lógicas clave en los flujos.
    • Líneas de Flujo: Guían el orden cronológico del proceso.

    Método de Aprendizaje
    100%
    Práctico
    Aprender Haciendo ("Learning by Doing")

    En esta materia no memorizarás teorías abstractas. Entrenarás tu mente resolviendo problemas del mundo real a través de retos, juegos lógicos y proyectos aplicados.

    La lógica es una habilidad práctica que se fortalece con cada problema resuelto, cada diagrama completado y cada error depurado.


    Contenido del Módulo 1

    Conceptos Básicos

    Introducción a la Diagramación

    Operadores 

    Probabilidades lógicas secuencias 

      

    El primer paso al éxito

    ¿Estás listo para el reto?

    ¡Nuevamente, bienvenidos! Prepárate para transformar tu forma de ver el mundo y resolver problemas.

     Prof. Lcda. Minerva Taborda (Lógica y Diagramación)
     Aula de Clases / Plataforma Virtual



  • COMPETENCIA ESPECíFICA

    El docente debe informar la competencia especifica de la asignatura 

    • Tema actual

      DATOS DEL DOCENTE:

      Profesor: MINERVA TABORDA

      Sección Según la Especialidad:

      Semestre: 1

      Datos de Contacto:

        *  Número de Teléfono: 04244329119

        *  WhatsApp: 04244329119

        *  Correo: taboraminerva@gmail.com

      HORARIO DE ASESORÍA:

      Asesoría: Explicación para actividades o contenidos asignados.

       – De 1:00 pm A 6:30 PM 


      Observación: 

      • Semana No. 9: PROYECTO FINAL MODULO I

        EVALUACIONES DEL PRIMER MODULO


        5% ALGORITMOS

        5% ACTIVIDAD VARIABLES

        25% CONDICIONAL SIMPLE 

        15% FUNCIÓN MOD

        25% EJERCICIOS PROPUESTOS (TODOS)

        25% PROYECTO FINAL (fecha de entrega 30/07/2026)


        Notas finales 

        Pablo Diaz   nota definitiva modulo I (Dieciocho) 18

        Elier García                                     (diecisiete) 17

        José Medina                                    (dieciseis) 16

        Yomackel Melendez                          (Dieciocho)18

        José García                                     (Diesisiete)17

        Ricardo Ochoa                                 (catorce)14

        José Tortolero                                  (diecisiete) 17

        Reywis Veliz                                    (Dieciocho) 18

        Mariana Vitriago                              ?

         




      • MODULO II LÓGICA Y DIAGRAMACIÖN

        • Semana No. 1: Módulo 2

          saludos estimados estudiantes feliz sábado 15 de agosto inicio del módulo 2 de la materia Lógica y diagramación

          Actividades a evaluar: 

          Ejercicios propuestos Condicional Segun 25%

          Trabajo 10%(metodos de ordenamiento)

          ejercicios propuestos vectores y matrices 25%

          Ejercicios propuestos BUCLES 20%

          flujogramas 20% 

          Tema 1 Modulo II

          ESTRUCTURA CONDICIONAL Segun 

           Se llama según (equivalente a Switch en un lenguaje de programación)

           Permite evaluar una variable y tomar diferentes caminos según el valor que contenga.

          Sintaxis Básica 

          Según variable Hacer

              opción 1: 

                  instrucciones

              opción 2: 

                   instrucciones

          De Otro Modo:

                   instrucciones si no coincide con ninguna

          FinSegún


          Ejemplo 1 con Letras (Caracteres)

          carga una Seudocódigo  que le perita al usuario elige una opción mediante una letra en mayúscula 

          ('A', 'B' o 'C').


          Algoritmo Ejec_Letras

              Definir opcion Como Caracter

              Definir monto como entero

              

              Escribir "=== MENÚ DE ATENCIÓN ==="

              Escribir "A - Consultar Saldo"

              Escribir "B - Realizar Depósito"

              Escribir "C - Hablar con un Operador"

              Escribir "Ingrese una opción (A, B o C):"

              Leer opcion

              

              Segun opcion Hacer

                  "A":

                      Escribir "Su saldo actual es de $1,250.00"

                  "B":

                      Escribir "Por favor, ingrese el monto a depositar :."

                       leer monto

                      Escribir "el monto depositado es:", monto

                  "C":

                      Escribir "Conectando con un ejecutivo... Por favor espere en la línea."

                  De Otro Modo:

                      Escribir "Error: Opción no válida. Por favor ingrese A, B o C."

              FinSegun

          FinAlgoritmo


          Observa el video 

          https://youtu.be/bEhXn7AHEIo?si=CfvIl9guYtgRePVs



          Ejercicio 2 con Números (Enteros)

          Días de la semana: El usuario ingresa un número del 1 al 7 y el programa determina el día correspondiente.

          Algoritmo Ejercicio_Numeros

           Definir numeroDia Como Entero // declaramos la variable

           Escribir "Ingrese un número del 1 al 7 para conocer el día de la semana:"    //Pedimos el numero por pantalla 

           Leer numeroDia                                                                                                   

           Segun numeroDia Hacer 

               1: 

                 Escribir "El día 1 es Lunes." 

               2: 

                 Escribir "El día 2 es Martes." 

               3: 

                 Escribir "El día 3 es Miércoles." 

               4: 

                  Escribir "El día 4 es Jueves." 

               5: 

                 Escribir "El día 5 es Viernes." 

               6: 

                 Escribir "El día 6 es Sábado (¡Fin de semana!)." 

               7: 

                  Escribir "El día 7 es Domingo (¡Fin de semana!)."

               De Otro Modo: 

                  Escribir "Error: El número ingresado debe estar en el rango de 1 a 7." 

               FinSegun

          FinAlgoritmo


          Ejercicio Propuesto en la tarea 


        • Estructuras Ciclicas

          ▷ Bucles en Python: for y while - Guía completa [+Ejemplos] 2026


          ¿Qué es un bucle?

          Una estructura cíclica (o bucle) permite ejecutar un conjunto de instrucciones de forma repetida

          mientras se cumpla una condición.

           De tal modo que, Se llaman problemas repetitivos o cíclicos a aquellos en cuya solución es

          necesario utilizar un mismo conjunto de acciones que se puedan ejecutar una cantidad específica

          de veces. Esta cantidad puede ser fija (previamente determinada por el programador) o puede ser

          variable (estar en función de algún dato dentro del programa)

          para controlar el ciclo tenemos que formular una CONDICIÓN en donde el ciclo pueda parar y no

          sea infinito.

          NOTA: para controlar el buen funcionamiento de un ciclo utilizamos dos elementos los cuales son

          esenciales para controlar el ciclo. (Contador y Acumulador).

          CONTADOR

          Contador: Sintaxis: contador ++ o contador = contador+1

          - Esto significa que cada vez que el ciclo se ejecute el contador avanza una posición.

          - Al declarar el contador le otorgamos un valor de cero, cuando el ciclo se ejecute o+1=1

          - EL CONTADOR VALDRA AHORA 1 se vuelve a ejecutar el ciclo el contador se incrementa así

          Acumulador

          Un acumulador es una variable numérica que permite ir sumando valores uno tras otro para obtener un resultado total. Se inicializa generalmente en 0 si se trata de una suma, y cada nuevo valor ingresado se agrega al total acumulado mediante una operación como:

          acum <- acum + valor


          Estructura cíclica "PARA"

          El bucle Para es una estructura determinista: se utiliza cuando conocemos de antemano la cantidad exacta de veces que deseamos que se repita un bloque de código.

          Sintaxis en PSeInt

          Para variable_numerica <- valor_inicial Hasta valor_final Con Paso paso Hacer 

           // Secuencia de acciones a repetir 

          FinPara

          Ejercicio 1: Contador Básico (Incremento de 1 en 1)

          Problema: Imprimir los números enteros del 1 al 10 en pantalla.

          Algoritmo ContadorSimple

           Definir i Como Entero

           Escribir "Mostrando los números del 1 al 10:" 

             Para i <- 1 Hasta 10 Con Paso 1 Hacer 

           Escribir "Número: ", i

             FinPara 

          FinAlgoritmo


          Ejercicio 2: Tabla de Multiplicar (Uso del contador en operaciones)

          Problema: Solicitar al usuario un número e imprimir su tabla de multiplicar del 1 al 15.

          Algoritmo TablaMultiplicar 

            Definir num, i, resultado Como Entero 

           Escribir "Ingrese el número de la tabla del 1 hasta 15:" 

             Leer num

          Escribir "--- Tabla del ", num, " ---" 

           

           Para i <- 1 Hasta 15 Con Paso 1 Hacer

            resultado <- num * i 

           Escribir num, " x ", i, " = ", resultado 

            FinPara 

            FinAlgoritmo

          Ejercicio Propuesto 

          Crear un algoritmo que pida al usuario 5 calificaciones (números del 1 al 20). El programa debe calcular la suma total de las notas y mostrar el promedio final del estudiante.

          Pistas para los alumnos:

          Necesitarán una variable acumuladora (ej. suma <- 0) antes de iniciar el Para.

          Dentro del Para (de 1 a 5), deben leer la nota y sumarla al acumulador (suma <- suma + nota).

          Fuera del Para, calcular el promedio (promedio <- suma / 5).

           

          Observa el video de referencia:

          https://youtu.be/tHQLTppTi-A?si=g1Y7sQyrtDsXOHXw


          • ESTRUCTURAS CÍCLICAS MIENTRAS Y REPETIR

            ESTRUCTURAS CICLICA

            • MIESTRAS (WHILE)
            • REPETIR (DO WHILE)


            TEORÍA

            ·         Ciclo Mientras (While): Evalúa la condición antes de entrar al bucle (pre-prueba). Si la condición es falsa desde el inicio, el bloque de código nunca se ejecuta. Es ideal cuando no sabemos si el proceso debe ejecutarse al menos una vez.

             

            ·         Ciclo Repetir-Hasta Que (Do-While): Evalúa la condición al final del bucle (post-prueba). Garantiza que el bloque de código se ejecute al menos una vez, sin importar el valor inicial de la condición.

             

            Ejercicios para el Ciclo Mientras

            Ejercicio 1 Contador simple ascendente

            Muestra los números del 1 al 5 en pantalla.

            Algoritmo  bucles_MIENTRAS //Profe: Minerva Taborda

            Definir contador Como Entero

                 contador <- 1

            Mientras contador <= 5 Hacer

            Escribir "Número: ", contador

            contador <- contador + 1 // Incremento para evitar bucle infinito

            FinMientras

            FinAlgoritmo

             

             

             

             

                                            Ejercicio 2 (Guiado): Validación de clave de acceso

            Solicita una contraseña numérica hasta que el usuario ingrese la correcta (1234).

            Algoritmo  bucles_MIENTRAS //Profe: Minerva Taborda

                        Definir clave Como Entero

                        Escribir "Ingrese la clave secreta:"

                        Leer clave

                        Mientras clave <> 1234 Hacer

                                    Escribir "Clave incorrecta. Intente de nuevo:"

                                    Leer clave

                        FinMientras

                        Escribir "¡Acceso concedido!"

            FinAlgoritmo


             

             

             EJERCICIOS CICLO REPETIR

            Ejercicio 1: Menú de opciones básico

            Muestra un menú interactivo que se repite hasta que el usuario seleccione la opción de salir.

            Algoritmo  bucles_REPETIR //Profe: Minerva Taborda

                       

                                    Definir opc Como Entero

                                    Repetir

                                                Escribir "=== MENÚ ==="

                                                Escribir "1. Saludar"

                                                Escribir "2. Despedirse"

                                                Escribir "3. Salir"

                                                Leer opc

                                               

                                                Segun opc Hacer

                                                           1: Escribir "¡Hola! Bienvenido."

                                                           2: Escribir "¡Hasta luego!"

                                                           3: Escribir "Saliendo del programa..."

                                                           De Otro Modo: Escribir "Opción no válida."

                                                FinSegun

                                            Hasta Que opc = 3

                                FinAlgoritmo

             

             

             

             Ejercicio 2 (Guiado): Sumador de números positivos

            Suma números ingresados por el usuario hasta que se ingrese un número n

            Algoritmo  bucles_REPETIR //Profe: Minerva Taborda

            Definir num, suma Como Real

              suma <- 0

                   

            Repetir

                    Escribir "Ingrese un número positivo (negativo para terminar):"

                    Leer num

                    Si num >= 0 Entonces

                        suma <- suma + num

                    FinSi

                Hasta Que num < 0

               

                Escribir "La suma total es: ", suma

            FinAlgoritmo

             

             

             

             

             

             

             

             

             


            • Estructuras Ciclícas



              REPASO y Práctica


              Ejercicio 1 

              En PSeInt, la factorización (o descomposición en factores primos) consiste en descomponer un número entero positivo en el producto de sus números primos (por ejemplo, 12 = 2* 2 * 3).

              Para lograrlo, se utilizan estructuras cíclicas (Mientras o Para) probando divisores desde el número 2 en adelante.

              Algoritmo FactorizacionPrimos//profesora Minerva Taborda

              Definir num, divisor Como Entero

              Escribir "Ingrese un número entero positivo mayor a 1:"

              Leer num

              Si num <= 1 Entonces

              Escribir "El número debe ser mayor a 1."

              Sino

              Escribir "Los factores primos de ", num, " son:"

              divisor <- 2

              Mientras num > 1 Hacer

              // Si el divisor divide exactamente al número

              Si num % divisor == 0 Entonces

              Escribir divisor

              num <- num / divisor   // Reducimos el número

              Sino

              divisor <- divisor + 1     // Probamos con el siguiente divisor

              FinSi

              FinMientras

              FinSi

              FinAlgoritmo


              Comprobamos en un  PSeInt online 

              ¿Cómo funciona el algoritmo paso a paso?

              Ejemplo con el número 12:

              1. Inicialización: num = 12, divisor = 2.

              2. Iteración 1: 12 (mod 2) = 0. Muestra 2 y reduce num a 6 (12 / 2).

              3. Iteración 2: 6  (mod 2) = 0. Muestra 2 y reduce num a 3 (6 / 2).

              4. Iteración 3: 3  (mod 2) ≠ 0. El divisor incrementa a 3.

              5. Iteración 4: 3  (mod 2) = 0. Muestra 3 y reduce num a 1 (3 / 3).

              6. Fin: num ya no es mayor a 1, el ciclo termina. (Factores resultantes: 2, 2, 3).


              Ejercicio 2

              Mostrar los factores con sus potencias

              Si prefieres mostrar la respuesta agrupada con exponentes  por ejemplo12 = 22 * 31  

              Algoritmo FactorizacionConExponentes 

                Definir num, divisor, contador Como Entero 

                 Escribir "Ingrese un número entero positivo:" 

                 Leer num divisor <- 2 

                    Mientras num > 1 Hacer 

                     contador <- 0

                    Mientras num % divisor == 0 Hacer 

                      contador <- contador + 1 

                         num <- num / divisor

                  FinMientras 

                     Si contador > 0 Entonces 

                        Escribir divisor, "^", contador 

                    FinSi

                       divisor <- divisor + 1 

                       FinMientras

               FinAlgoritmo


            • Función Longitud(cadena) en

              Resultado de imagen de longitud de cadena peseint

              Función Longitud(cadena) con Bucles y Condicionales en PSeInt

              Objetivo: Comprender el funcionamiento interno de la función integrada Longitud(cadena) y aprender a replicar su comportamiento analizando carácter por carácter mediante bucles y condicionales.

              1. ¿Qué hace Longitud(cadena) en PSeInt?

              La función integrada Longitud(texto) devuelve la cantidad total de caracteres (incluyendo espacios, números y símbolos) que componen un texto.

              Ejemplo

              Algoritmo 1: Recorrido y Conteo Manual de Caracteres

              Para entender cómo funciona Longitud(), crearemos un bucle Para que recorra la cadena desde la posición 1 hasta Longitud(texto) utilizando la función Subcadena(texto, inicio, fin)


              Pseudocódigo

              Algoritmo ContarCaracteresManual //Profe Minerva Taborda

              Definir texto, letras Como Cadena

              Definir C, contador Como Entero

              Escribir "Ingrese una frase o palabra:"

              Leer texto

              contador <- 0

              // Recorremos la cadena carácter por carácter

              Para C <- 1 Hasta Longitud(texto) Con Paso 1 Hacer

              letra <- Subcadena(texto,C,C)

              contador <- contador + 1

              Escribir "Posición ", C, ": ", letras

              FinPara

              Escribir "----------------------------------"

              Escribir "Total de caracteres contados: ", contador

              Escribir "Verificación con Longitud(): ", Longitud(texto)

              FinAlgoritmo




              Algoritmo 2: Filtrado con Condicionales (Contar vocales y consonantes/espacios)

              Combinando Longitud() con la estructura Si-Entonces, podemos evaluar qué tipo de carácter hay en cada posición.

              Pseudocódigo

              Algoritmo AnalizarTexto // Minerva Taborda

                  Definir texto, letras Como Cadena

                  Definir i, cant_vocales, cant_cons Como Entero

                  

                  Escribir "Ingrese un texto para analizar:"

                  Leer texto

                  

                  cant_vocales <- 0

                  cant_otros <- 0

                  

                  Para i <- 1 Hasta Longitud(texto) Con Paso 1 Hacer   //bucle para 

                      letras <- Mayusculas(Subcadena(texto, i, i))

                      

                              Si letras = "A" O letras = "E" O letras = "I" O letras = "O" O letras = "U" Entonces  //condicional

                          cant_vocales <- cant_vocales + 1

                      Sino

                          cant_cons <- cant_cons + 1

                      FinSi

                  FinPara

                  

                  Escribir "Resultados del análisis:"

                  Escribir "Longitud total: ", Longitud(texto)

                  Escribir "Total de vocales: ", cant_vocales

                  Escribir "Total de consonantes, espacios o símbolos: ", cant_cons

              FinAlgoritmo


            • FUNCIÓN ConvertirANumero() : Conversión de Cadenas a Números en PSeInt

              PSeInt

              Con la función integrada ConvertirANumero(cadena), aprenden a validar entradas de texto antes de procesarlas matemáticamente además nos permite aplicar bucles y condicionales para la conversión y análisis de datos.

              ¿Qué hace ConvertirANumero(cadena) en PSeInt?

              La función ConvertirANumero(texto) toma una cadena de caracteres que contiene dígitos numéricos (por ejemplo, "125" o "45.6") y la transforma en un valor numérico real o entero para poder realizar operaciones matemáticas.

              Importante: Si la cadena contiene letras o símbolos no numéricos (ej. "ABC" o "12a"), el programa generará un error de ejecución.

              EJEMPLO

              Algoritmo 2: Suma de Dígitos Extraídos de una Cadena

              En este ejemplo, usamos Longitud() para recorrer un texto, extraemos cada carácter numérico con Subcadena(), lo convertimos individualmente con ConvertirANumero() y acumulamos el resultado.

                Algoritmo SumarDigitosDeCadena //Profe: Minerva TAborda

                  Definir texto, digitoS Como Cadena

                  Definir C, digitoN, suma_total Como Entero

                  

                  Escribir "Ingrese una serie de dígitos (ejemplo: 4582):"

                  Leer texto

                  

                  suma_total <- 0

                  

                  Para C <- 1 Hasta Longitud(texto) Con Paso 1 Hacer

                      digitoS <- Subcadena(texto, C, C)

                      

                      // Evaluamos si el carácter individual es un dígito válido

                      Si digitoS >= "0" Y digitoS <= "9" Entonces

                          digitoN <- ConvertirANumero(digitoS)

                          suma_total <- suma_total + digitoN

                          Escribir "Dígito en posición ", C, ": ", digitoN

                      Sino

                        Escribir "Caracter", digitoS, "ignorado (no es un dígito)."

              FinSi

                  FinPara

                  

                  Escribir "----------------------------------"

                  Escribir "La suma total de los dígitos es: ", suma_total

              FinAlgoritmo




            • Vectores (Arreglos Unidimensionales) en PSeInt

              Resultado de imagen de vector programacion

              Vectores (Arreglos Unidimensionales)

              Un vector (también llamado arreglo unidimensional) en programación es una estructura de datos que permite almacenar una serie de elementos del mismo tipo en orden y bajo un mismo nombre de variable. 

              Sirven para agrupar múltiples datos relacionados (como una lista de 10 notas o 5 nombres) sin necesidad de crear una variable independiente para cada uno. Se accede a cada elemento mediante un índice o posición numérica.

              Se usan cuando necesitas procesar colecciones de datos (guardar, buscar, ordenar, modificar o mostrar muchos valores repetidos) utilizando estructuras de repetición como los bucles Para (For)

              Tipos de vectores (en programación)
              Se clasifican según el tipo de dato que guardan:
              • Numéricos: Enteros (Como Entero) o decimales/reales (Como Real).
              • Caracteres / Texto: Cadenas de caracteres (Como Carácter o Como Cadena).
              • Lógicos: Valores verdaderos o falsos (Como Lógico).

              Ejemplo de tipo : numéricos 

              números (10, 20, 30, 40, 50) todos estos elementos son números enteros 

              El elemento 10 siempre está en la posición (índice) 0, el 20 en la posición 1, y así sucesivamente.

              Ejemplo Tipo Carácter:

              nombres = ("Ana", "Luis", "Carlos", "Sofía")

              Ejemplo Tipo Lógicos:

              Índice (Posición)     0        1           2        3

              Valor Lógico    true   false  false  true

              Características clave:

              • Homogéneo: Todos los elementos almacenados en el vector deben ser del mismo tipo de dato (todos enteros, todos reales, todos textos, etc.).

              • Indexado: Cada elemento tiene asignada una posición única llamada índice. En la configuración estándar de PSeInt, los índices comienzan en 1.

              • Tamaño Fijo: El tamaño del vector se define al momento de declararlo mediante la palabra reservada Dimension y no puede modificarse durante la ejecución del programa.

              • Acceso Directo: Se puede acceder a cualquier elemento del vector de forma directa usando su índice, por ejemplo: miVector[3].

                      Para trabajar con vectores en PSeInt se siguen tres pasos fundamentales: 

              1. definición de variables, 

              2. Dimensión 

              3. Manipulación mediante ciclos (generalmente la estructura Para).

              Ejemplo 1: Cálculo de Promedio de Combustible

              Contexto: Un chofer de transporte necesita registrar el consumo de combustible (en litros) durante los 5 días de la semana laboral para obtener el promedio diario y detectar qué día consumió más.

              Pseudocòdigo 

              Algoritmo Con_Combustible//profe Minerva

              Dimension consumo[5]

              Dimension dias[5]

                            

              // Carga de nombres de los días de consumo por litro

              dias[1] <- "Lunes"

              dias[2] <- "Martes"

              dias[3] <- "Miércoles"

              dias[4] <- "Jueves"

              dias[5] <- "Viernes"

                            

              Definir suma, promedio, maxConsumo Como Real

              Definir i, posMax Como Entero    

                     suma <- 0

                            

              Escribir "=== REGISTRO DE CONSUMO DE COMBUSTIBLE ==="

                            

              Para i <- 1 Hasta 5 Con Paso 1 Hacer

              Escribir "Ingrese litros consumidos el día ", dias[i], ":"

              Leer consumo[i]

                             suma <- suma + consumo[i]

              FinPara

                    

                    promedio <- suma / 5

                            

              // Búsqueda del día con mayor consumo

                    maxConsumo <- consumo[1]

                           posMax <- 1

               

              Para i <- 2 Hasta 5 Con Paso 1 Hacer

                    Si consumo[i] > maxConsumo Entonces

                             maxConsumo <- consumo[i]

                             posMax <- i

              FinSi

              FinPara

                            

              // Reporte final

              Escribir "-------------------------------------------"

              Escribir "Total de litros consumidos en la semana: ", suma, " Litro"

              Escribir "Promedio diario de consumo: ", promedio, " Litro"

              Escribir "El mayor consumo fue el día ", dias[posMax], " con ", maxConsumo, " Litro"

               FinAlgoritmo

               



              Algoritmo ArqueoCaja   // Profe Minerva

              Dimension denominaciones[6]
              Dimension cantidades[6]
              denominaciones[1] <- 1
              denominaciones[2] <- 5
              denominaciones[3] <- 10
              denominaciones[4] <- 20
              denominaciones[5] <- 50
              denominaciones[6] <- 100
              Definir total_Caja, subtotal Como Real
              Definir i Como Entero
              Total_Caja <- 0
              Escribir "=== CONTEO DE BILLETES EN CAJA ==="
              Para i <- 1 Hasta 6 Con Paso 1 Hacer
              Escribir "Ingrese cantidad de billetes de $", denominaciones[i], ":"
              Leer cantidades[i]
              subtotal <- cantidades[i] * denominaciones[i]
              total_Caja <- total_Caja + subtotal
              FinPara
              Escribir "-------------------------------------------"
              Escribir "RESUMEN DE CAJA:"
              Para i <- 1 Hasta 6 Con Paso 1 Hacer
              Escribir cantidades[i], " billetes de $", denominaciones[i], " = $", cantidades[i] * denominaciones[i]
              FinPara
              Escribir "-------------------------------------------"
              Escribir "Monto total acumulado en caja: $", total_Caja
              FinAlgoritmo






              • MATRICES (arreglos bidimensionales)


                Lógica de programación

                MATRICES (arreglos bidimensionales)

                Una matriz (o arreglo bidimensional) Una matriz (o arreglo bidimensional) es una estructura de datos homogénea y ordenada que organiza elementos en forma de tabla o cuadrícula. A continuación se detallan sus características principales agrupadas por su comportamiento conceptual y técnico en programación:


                Para acceder o modificar un elemento específico, se necesitan dos índices:

                1. Índice de Fila (i): Posición vertical.

                2. Índice de Columna (j): Posición horizontal


                Estructurales

                • Estructura Bidimensional: Se compone de dos dimensiones principales: filas (horizontales) y columnas (verticales).

                • Dimensión o Tamaño (m x n): Se define por el número de filas (m) y el número de columnas (n). 

                        Una matriz de 3 x 4 tiene 3 filas y 4 columnas, dando un total de 12 elementos (m . n).


                • Identificación por Índices: Cada elemento ocupa una posición única dentro de la matriz y se accede a él mediante un par de subíndices [i, j]:

                  • i: Representa el número o posición de la fila.

                  • j: Representa el número o posición de la columna.

                Técnicas y de Memoria

                • Homogeneidad: Todos los datos o valores contenidos dentro de una misma matriz deben ser estrictamente del mismo tipo de dato (por ejemplo: todos enteros, todos reales o todas cadenas de texto).

                • Acceso Directo (Aleatorio): Se puede acceder a cualquier casilla de la matriz de manera inmediata conociendo sus índices [i, j], sin necesidad de recorrer los elementos anteriores.

                • Almacenamiento en Memoria Contigua: Internamente, la memoria de la computadora reserva un bloque continuo para almacenar la totalidad de sus elementos.

                • Estática (en la mayoría de los lenguajes de programación tradicionales o simulador como PSeInt): Su tamaño (m x n) debe ser definido antes o al momento de ser declarada y, por lo general, no se puede modificar durante la ejecución del programa.

                Operacionales

                • Manipulación mediante Ciclos Anidados: Para recorrer, llenar o procesar todos sus elementos, se requiere el uso de dos bucles o estructuras repetitivas anidadas (un ciclo exterior para controlar las filas y un ciclo interior para las columnas).

                • Base de Indexación: Según la configuración o el lenguaje de programación, el conteo de los índices puede iniciar en:

                  • Base 1: El primer elemento es [1, 1] (configuración predeterminada en PSeInt).

                  • Base 0: El primer elemento es [0, 0] (estándar en C, C++, Java, Python, entre otros).


                Sintaxis en PSeInt:

                Dimension nombreMatriz[cantidadFilas, cantidadColumnas]

                Para procesar o llenar una matriz, se utilizan ciclos anidados (Para dentro de otro Para):

                • El ciclo externo controla las filas.

                • El ciclo interno controla las columnas.

                   Para i <- 1 Hasta filas Hacer 

                      Para j <- 1 Hasta columnas Hacer  

                // Operaciones con nombreMatriz[i, j] 

                       FinPara

                          FinPara

                Ejemplo:

                Creación, Llenado y Lectura de una Matriz de 2 X 3

                Este programa solicita al usuario ingresar valores enteros y luego los imprime en pantalla con formato de cuadrícula.


                Algoritmo MatrizUNO //PROFE MINERVA 

                    Definir i, j Como Entero

                    Definir matriz Como Entero

                    Dimension matriz[2,3]

                    

                    // Llenado de la matriz

                    Escribir "=== INGRESO DE DATOS DE LA MATRIZ (2x3) ==="

                    Para i <- 1 Hasta 2 Hacer

                        Para j <- 1 Hasta 3 Hacer

                            Escribir "Ingrese el valor para la posición [", i, ",", j, "]:"

                            Leer matriz[i,j]

                        FinPara

                    FinPara

                    

                    // Impresión de la matriz

                    Escribir ""

                    Escribir "=== MATRIZ INGRESADA ==="

                    Para i <- 1 Hasta 2 Hacer

                        Para j <- 1 Hasta 3 Hacer

                            Escribir matriz[i,j], " " Sin Bajar

                        FinPara

                        Escribir "" // Salto de línea por cada fila

                    FinPara

                FinAlgoritmo

                EJERCICIO 2

                Suma de Elementos de una Matriz

                Cálculo de la suma total y el promedio de los elementos contenidos en una matriz de 3X3

                Algoritmo SUMARYPROMEDIAR// PROFE MINERVA

                    Definir E, G Como Entero

                    Definir matriz, suma Como Real

                    Dimension matriz[3,3]

                    suma <- 0

                    

                    // Llenado automático con valores de prueba

                    Escribir "Cargando datos..."

                    Para E <- 1 Hasta 3 Hacer

                        Para G <- 1 Hasta 3 Hacer

                            matriz[E,G] <- E * G + 2

                            suma <- suma + matriz [E,G]

                        FinPara

                    FinPara

                    

                    // Mostrar la matriz

                    Para E <- 1 Hasta 3 Hacer

                        Para G <- 1 Hasta 3 Hacer

                            Escribir matriz[E,G], "   " Sin Bajar

                        FinPara

                        Escribir ""

                    FinPara

                    

                    Escribir "TOTAL suma de es: ", suma

                    Escribir "SU PROMEDIO: ", suma / 9

                FinAlgoritmo


                • EVALUACION VECTORES Y MATRICES

                  1. EVALUACION VECTORES Y MATRICES 25%





                  DESCARGA EL ARCHIVO Y REALIZA LOS SIGUIENTES EJERCICIOS DE VECTORES Y MATRICES: 

                • Flujogramas

                  flujograma impreso en un papel

                  ¿Qué es un flujograma?

                  Según: Flujograma - Qué es, características, tipos y ejemplos

                  Un flujograma es una representación visual de un proceso o sistema, que ilustra la secuencia de pasos a seguir para alcanzar un objetivo determinado. Se construye utilizando una variedad de símbolos estandarizados, cada uno de los cuales representa diferentes tipos de acciones o decisiones. Los flujogramas son particularmente útiles en el ámbito empresarial, y técnico, ya que permiten visualizar de manera clara y concisa procedimientos complejos, facilitando así la comprensión y el análisis.

                  Los flujogramas no solo sirven para documentar procesos existentes, sino que también son herramientas valiosas para la identificación de áreas de mejora, la formación de personal nuevo, e incluso en la gestión de proyectos. Al desglosar un proceso en sus pasos fundamentales, es más fácil entender cómo interactúan los distintos componentes y dónde pueden surgir problemas.

                  Características de un flujograma

                  Un diagrama de flujo se caracteriza por lo siguiente:

                  • Está compuesto por símbolos, flechas y texto. Sus símbolos indican qué tipo de paso es cada uno, el texto designa el paso y las flechas o líneas indican la secuencia.
                  • Es sintético, secuencial y estructurado. Muestra todos los pasos implicados en un proceso de manera resumida e indicando su secuencia.
                  • Muestra visualmente la toma de decisiones. Mediante un símbolo específico, indica que hay dos caminos posibles dentro un procedimiento.
                  • Representa de manera fácil un proceso complejo. Muestra de forma concreta y simple procesos que tienen muchos pasos o en los que intervienen varias decisiones.
                  • Es utilizado en diferentes disciplinas. Se emplea para indicar procesos logísticos u organizacionales en informática, distintas industrias, empresas, instituciones, entre otros.
                  • Se aplica para realizar distintas actividades. Se usa para tomar decisiones importantes; planificar, dirigir y evaluar procedimientos; realizar capacitaciones; detectar inconvenientes en una tarea; organizar actividades, entre otros fines.

                  Simbología:


                  Algoritmos y Diagramas de Flujo


                  Tipos de flujograma

                  Existen distintos tipos de flujograma que se clasifican en dos grandes grupos: flujogramas lineales y flujogramas matriciales.

                  1. Flujogramas lineales

                  Los flujogramas lineales son aquellos cuyo proceso puede seguirse de manera simple y secuencial, ya que los pasos o instancias se encuentran uno después del otro.

                  • Flujogramas verticales. La secuencia de operaciones va de arriba abajo, las actividades se colocan en una columna y los símbolos en la primera fila. Se utiliza una línea para mostrar la secuencia del procedimiento. Por ejemplo:
                  ejemplo de diagrama de flujo vertical
                  • Flujogramas horizontales. La secuencia de operaciones va de izquierda a derecha. Cada paso se coloca en un símbolo y van unidos con flechas. Por ejemplo:
                  ejemplo de diagrama de flujo horizontal
                  • Flujogramas panorámicos. La secuencia se distribuye en distintos bloques, que agrupan un conjunto de tareas.  Por ejemplo:
                  ejemplo de diagrama de flujo

                  2. Flujogramas matriciales

                  Los flujogramas matriciales son aquellos en los que, además de incluir pasos y decisiones, se mencionan los agentes o los responsables, es decir, las personas o las áreas encargadas de cada tarea. Pueden ser verticales u horizontales. Por ejemplo:

                  ejemplo de flujograma matricial

                  ¿Cómo hacer un flujograma?

                  Para hacer un flujograma de manera simple y correcta, pueden seguirse los siguientes cuatro pasos:

                  • Comprender el proceso. El paso inicial para el flujograma es elegir y comprender el proceso que se quiere describir gráficamente. Conviene entender cuál es el propósito del flujograma y a qué público apunta.
                  • Identificar los elementos. Una vez comprendido el proceso, se deben identificar sus pasos y cómo van ordenados, sus puntos de inicio y fin y sus decisiones clave, y elegir los símbolos adecuados para cada uno.
                  • Ir paso a paso. La construcción del flujograma implica establecer, paso a paso, cada símbolo y cada línea conectora. Se debe tener en cuenta la superficie (hoja o pantalla) en la que se está creando el flujograma, especialmente en los procesos complejos, para no crear un diagrama difícil de seguir a simple vista.
                  • Recorrer el diagrama. Una vez terminado el diagrama de flujo, se debe volver al inicio y recorrer el flujo entero, para verificar que no existan callejones sin salida, ambigüedades ni errores procedimentales. Es importante tener en cuenta que, una vez finalizado, puede ser consultado por terceros sin contar con la orientación de quien lo creó, por lo que debe ser un diagrama simple, pero completo.

                  Ejemplos de flujograma

                  1. Flujograma de compra de unos zapatos
                  ejemplo de diagrama de flujo para la compra de zapatos




                  • Evaluación final

                    Estimados estudiantes les envío este link para que ingresen a su última actividad solo pueden resolver el test una sola vez tiene y enviar por el WhatsApp un capture de la nota resultante al contestar en test costa de tres partes

                    1 teoría 

                    2 jugos (sopa de letras y crucigrama) este tiene temporizador 

                    3 completar los algoritmos 

                    Link

                  •  actividad_flujogramas_pseint.html 


                  • Puedes abrirlo directamente en cualquier navegador (Chrome, Edge, Firefox, Safari)

                  • SUERTE 





                  • Nota  modulo II y definitiva de la materia .... Nota MII              Definitiva

                  • Pablo Diaz                                             (Diecinueve) 19               19

                    Elier García                                           (doce) 12                         15

                    José Medina                                          (cinco) 05                         11

                    Yomackel Melendez                                (Diecinueve)19                 18

                    José García                                           (Diecinueve)19                  18

                    Ricardo Ochoa                                      (Quince)15                        15

                    José Tortolero                                       (diecinueve) 19                  19

                    Reywis Veliz                                         (veinte) 20                         19

                    Mariana Vitriago                                     (cero)                            ?


                  • Suerte en su próximo semestre.  Sigan acumulando excelentes notas felicidades